home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 3: CDPD 3 / Almathera Ten on Ten - Disc 3: CDPD3.iso / fish / 726-750 / 741 / rkrm_devices / rkrm_devices.lha / Resources / Alloc_Misc.a < prev    next >
Text File  |  1992-09-03  |  4KB  |  114 lines
  1. *
  2. * Copyright (c) 1992 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. ******************************************************************************
  27. *
  28. * Alloc_Misc.a
  29. *
  30. * Assembly language fragment that grabs the two parts of the serial
  31. * resource (using misc.resource).  If it gets the resource, it will
  32. * wait for CTRL-C to be pressed before releasing.
  33. *
  34. * While we are waiting, the query_serial program should be run.  It will try
  35. * to open the serial device and if unsuccessful, will return the name of the
  36. * owner.  It will be us, Serial Port Hog!
  37. *
  38. * When a task has successfully obtained the serial resource, it "owns"
  39. * the hardware registers that control the serial port.  No other tasks
  40. * are allowed to interfere.
  41. *
  42. * Assemble with Adapt
  43. *     HX68 Alloc_Misc.a to Alloc_Misc.o
  44. *
  45. * Link
  46. *     Blink FROM Alloc_Misc.o TO Alloc_Misc LIB LIB:amiga.lib
  47. *
  48. *
  49. *               CSECT Alloc_Misc ; SAS/Lattice ASM command needs this
  50. *
  51.                 INCDIR  "include:"
  52.                 INCLUDE "exec/types.i"
  53.                 INCLUDE "resources/misc.i"
  54.                 INCLUDE "dos/dos.i"
  55.  
  56.         xref    _AbsExecBase     ; We get this from outside...
  57.         xref    _LVOOpenResource ; We get this from outside...
  58.         xref    _LVOWait         ; We get this from outside...
  59.  
  60. ;
  61. ; Open Exec and the misc.resource, check for success
  62. ;
  63.                 move.l  _AbsExecBase,a6         ;Prepare to use exec
  64.                 lea.l   MiscName(pc),a1
  65.                 jsr    _LVOOpenResource(a6)    ;Open "misc.resource"
  66.                 move.l  d0,d7                   ;Stash resource base
  67.                 bne.s   resource_ok
  68.                 moveq   #RETURN_FAIL,d0
  69.                 rts
  70.  
  71. resource_ok     exg.l   d7,a6                   ;Put resource base in A6
  72.  
  73. ;
  74. ; We now have a pointer to a resource.
  75. ; Call one of the resource's library-like vectors.
  76. ;
  77.                 move.l  #MR_SERIALBITS,d0       ;We want these bits
  78.                 lea.l   MyName(pc),a1           ;This is our name
  79.                 jsr     MR_ALLOCMISCRESOURCE(a6)
  80.                 tst.l   d0
  81.                 bne.s   no_bits                 ;Someone else has it...
  82.                 move.l  #MR_SERIALPORT,d0
  83.                 lea.l   MyName(pc),a1
  84.                 jsr     MR_ALLOCMISCRESOURCE(a6)
  85.                 tst.l   d0
  86.                 bne.s   no_port                 ;Someone else has it...
  87.  
  88. ;
  89. ; We just stole the serial port registers; wait.
  90. ; Nobody else can use the serial port, including the serial.device!
  91. ;
  92.                 exg.l   d7,a6                   ;use exec again
  93.                 move.l  #SIGBREAKF_CTRL_C,d0
  94.                 jsr    _LVOWait(a6)            ;Wait for CTRL-C
  95.                 exg.l   d7,a6                   ;Get resource base back
  96. ;
  97. ; Free 'em up
  98. ;
  99.                 move.l  #MR_SERIALPORT,d0
  100.                 jsr     MR_FREEMISCRESOURCE(a6)
  101. no_port
  102.                 move.l  #MR_SERIALBITS,d0
  103.                 jsr     MR_FREEMISCRESOURCE(a6)
  104. no_bits
  105.                 moveq   #RETURN_FAIL,d0
  106.                 rts
  107. ;
  108. ; Text area
  109. ;
  110. MiscName        dc.b    'misc.resource',0
  111. MyName          dc.b    'Serial Port Hog',0
  112.                 dc.w    0
  113.                 END
  114.